next up previous contents index
Next: Producing Images Up: Baseline determination Previous: a rough, simple way   Contents   Index

more sophisticated

In this we first process the data into a secondary file, perform a RF passband calibration to be able to average continuum subbands and sidebands more accurately, and solve for the baseline with a search loop.

!
FILE I INTER_DATA:01-dec-1992         !  Load the raw data
SET SCAN 2393 2440                    ! select data by scan number
SET PROCEDURE CORR                    ! only correlations
FIND
LIST                                  ! as a check
FILE O W00-N15-E23 NEW                ! open a secondary data file
COMPRESS 60                           ! compress to 1 minute, 
                                      ! (this saves plotting time)
!
! Select the compressed data file and do passband calibration on 3c273
!
FILE BOTH W00-N15-E23                 ! reopen for both input and output
FIND                
PLOT                                  ! giving it a glance does not hurt ...
SET SOURCE 3C273                      ! the strongest souce
SET MODE SPEC                         ! actually not needed
SET X I_F                             ! 
SET PHASE CONTINUOUS                  ! 
SET RF FREQUENCY                      ! use frequency dependent mode
SET Y AMPLITUDE  PHASE
SET SUBBANDS L01 TO L06
FIND 
LIST
SET BANDS UPPER                       ! do upper side band fist
SOLVE RF_PASSBAND 5 10 /PLOT          ! degrees as actually needed ...
SET BANDS LOWER                       ! Then lower side band
SOLVE RF_PASSBAND 5 10 /PLOT
SET SOURCE *                          ! come back to all sources
FIND
STORE RF_PASSBAND                     ! in place, in the data headers
!
! Now solve for baseline, using average of subbands 1 to 6
!
SET RF_PASSBAND ON  FR                ! from now on, plot calibrated data
SET MODE TIME                         ! switch back to time mode
SET SUBBANDS C01 TO C06               ! now subbands may be averaged
SET PHASE JUMPY                       ! best for baseline solving
SET Y PHASE                           ! amplitude not needed
SET X HOUR_ANGLE DECLINATION
SET BANDS AVERAGE                     ! double side band 
PLOT                                  ! phases should be displayed
SOLVE BAS/SEARCH                      ! should normally be enough.
                                      ! ...wait a few seconds ...
PRINT BASELINE
PAUSE                                 ! keep a log of the results !
RESIDUALS BASELINE                    ! phases should be flat.



Gildas manager 2018-10-15