next up previous contents index
Next: Interferometry Up: Reduction method Previous: Reduction method   Contents   Index

Single-dish

Single-dish data are analysed using CLASS by Gaussian fits with the method CONTINUUM Beam_size which takes into account the dual-beam pattern in elevation. Beam width, beam separation and beam ratios are fixed for better sensitivity. One planets, these parameters are freed using the GAUSS * * * command, since the planets are marginally resolved. The beam-size is 56 $''$ at 86 GHz.

A typical sequence of single-dish flux reduction is the following:

FIL IN 'date'.BUR
FIL OUT 'flux-date'.BUR      !
@ PR:INIT_FLUX Teles Line    ! Initialize once
R Scan
...
R Scan      ! Repeat for all scans in the file
!
@ PR:INIT_FLUX Teles Line    ! Repeat for other frequencies/Telescopes
...
R Scan

The setup procedure PR:INIT_FLUX contains

! @ PR:INIT_FLUX Telescope Line
! Initialize a flux data reduction
LAS\SET TEL &1           ! Select Telescope 
LAS\SET LINE &2          ! Select Observed Line
LAS\SET TYPE CONTINUUM
LAS\SET ALIGN POSITION
LAS\SET ANGLE SECOND
DEVICE                   ! Enter graphics device
SIC\DEFINE REAL F
SAY "Enter LO1 frequency in GHz (0 if not known or variable)"
LET F
IF (F.GT.80.AND.F.LT.118) THEN
   Say "The beam-size is:" '86*56|F'  
   ANALYSE\METHOD CONTINUUM 86*56|F     ! Fix the beam width
ELSE
   ANALYSE\METHOD CONTINUUM             ! Let it free if frequency not known
ENDIF
SYMBOL R "SIC\@ PR:FLUX"

R is a symbol calling the reduction procedure PR:FLUX.CLASS

!
! CLASS : Reduce a Pointing cross scan to get flux measurements
!
! Calling sequence : @ PR:INIT_FLUX
! Then R Scan_Number (R = "@ PR:FLUX")
!
DEFINE INTEGER ISCAN
DEFINE LOGICAL PLANET
LET ISCAN &1
LAS\FIND/SCAN ISCAN
LET PLANET (SOURCE.EQ."JUPITER".OR.SOURCE.EQ."VENUS".OR.SOURCE.EQ."MARS".OR.-
SOURCE.EQ."SATURN") 
!
LAS\GET FIRST
LAS\GET NEXT
LAS\ACCUMULATE
SET MOD X -110 110
LAS\PLOT
SIC\IF PLANET THEN
   ANALYSE\GAUSS * * *
ELSE
   ANALYSE\GAUSS
ENDIF
ANALYSE\FIT
PAUSE   "WRITE the result if it seems OK"
LAS\GET NEXT
LAS\GET NEXT
LAS\ACCUMULATE
SET MOD X -110 230
LAS\PLOT
SIC\IF PLANET THEN
   ANALYSE\GAUSS * * *
ELSE
   ANALYSE\GAUSS
ENDIF
ANALYSE\FIT
PAUSE "WRITE the result if it seems OK"
SET MOD X -110 110

When all the reduction is finished, print the fit results from the output file

FIL IN 'flux-date'.BUR
FIND
PRINT FLUX/OUT 'bur*-frequency-date'.FIT

The Gaussian fit results are written in a special file (produced by the new command CLASS PRINT FLUX /OUTPUT Filename) which contains all the fit parameters, the antenna number, the signal and image frequencies, the gain USB/LSB and the elevation of the source.

This file is then directly analysed using ASTRO with the new language FLUX which corresponds to the commands described in section 4.



Gildas manager 2018-06-16